Arama PMAX AL-SAT ART/C ile

Question

Merhabalar Kıvanç Beyin hazırlamış olduğu PMAX indikatörünü bir başka indikatör ile kullanmak istiyorum ( Ufak bir değişikilik ile ART periyodu fiyata bölünmüş durumda)

Koşulu CROSS ile değil BÜYÜKTÜR KÜÇÜKTÜR ile oluşturmak istiyorum (Diğer indikatör ile koşullu bağlayacağım için) Bir kaç deneme yaptım sonuç alamadım

Sizden ricam Cross(PMax,K) yerine Büyüktür veya Küçüktür koşulunu nasıl gerçekleştirebilirim, şimdiden yardımlarınız için teşekkür ederim

period:=opt1;
coeff:=opt2;
MovPeriod:=opt3;
K:=MOV((H+L)/2,MovPeriod,E);
OFFSET:=coeff*ATRe(period)/c;
STR:=K+OFFSET;
STS:=K-OFFSET;
FUB:=IF(STR<PREV OR REF(K,-1)>PREV,STR,PREV);
FLB:=IF(STS>PREV OR REF(K,-1)<PREV,STS,PREV);
PMax:=IF(PREV=REF(FUB,-1) AND K<FUB,FUB,IF(PREV=REF(FUB,-1) AND K>FUB,FLB,IF(PREV=REF(FLB,-1) AND K>FLB,FLB,IF(PREV=REF(FLB,-1) AND K<FLB,FUB,FUB))));
cross(K,PMax)

Answer 1

Merhabalar,

Aşağıdaki şekilde deneyebilirsiniz,

AL

period:=opt1;
coeff:=opt2;
MovPeriod:=opt3;
K:=MOV((H+L)/2,MovPeriod,E);
OFFSET:=coeff*ATRe(period)/c;
STR:=K+OFFSET;
STS:=K-OFFSET;
FUB:=IF(STR<PREV OR REF(K,-1)>PREV,STR,PREV);
FLB:=IF(STS>PREV OR REF(K,-1)<PREV,STS,PREV);
PMax:=IF(PREV=REF(FUB,-1) AND K<FUB,FUB,IF(PREV=REF(FUB,-1) AND K>FUB,FLB,IF(PREV=REF(FLB,-1) AND K>FLB,FLB,IF(PREV=REF(FLB,-1) AND K<FLB,FUB,FUB))));
K>PMax

SAT

period:=opt1;
coeff:=opt2;
MovPeriod:=opt3;
K:=MOV((H+L)/2,MovPeriod,E);
OFFSET:=coeff*ATRe(period)/c;
STR:=K+OFFSET;
STS:=K-OFFSET;
FUB:=IF(STR<PREV OR REF(K,-1)>PREV,STR,PREV);
FLB:=IF(STS>PREV OR REF(K,-1)<PREV,STS,PREV);
PMax:=IF(PREV=REF(FUB,-1) AND K<FUB,FUB,IF(PREV=REF(FUB,-1) AND K>FUB,FLB,IF(PREV=REF(FLB,-1) AND K>FLB,FLB,IF(PREV=REF(FLB,-1) AND K<FLB,FUB,FUB))));
K<PMax

Ayrıca, PMAX artık gömülü olarak mevcuttur.

AL

Cross(mov((H+L)/2,5,E),PMax(10,3,5,(H+L)/2,E))

SAT

Cross(PMax(10,3,5,(H+L)/2,E),mov((H+L)/2,5,E))

opt li

AL

cross(MOV((H+L)/2,opt3,e),PMax(opt1,opt2,opt3,(H+L)/2,E))

SAT

cross(PMax(opt1,opt2,opt3,(H+L)/2,E),MOV((H+L)/2,opt3,E))

büyüktür küçüktür olarak;

AL

MOV((H+L)/2,opt3,e)>PMax(opt1,opt2,opt3,(H+L)/2,E)

SAT

MOV((H+L)/2,opt3,e)<PMax(opt1,opt2,opt3,(H+L)/2,E)

İyi Çalışmalar

Comments

selam opt değerlerini yazabilirmisiniz teşekkürler

---

bu şekilde deneyebilirsiniz,

iyi çalışmalar