camarılla formul

Question

camarılla üç aylık formulu yazabilirmısınız.

asagıdakı formul aylık.

NW:=ROC(MONTH()<>ref(MONTH(),-1),1,$)<0;

x1t:=LastValue(ValueWhen(1,NW=-1,Cum(1)));

WH:=ValueWhen(1,Nw,Ref(HighestSince(1,Nw,H),-1));

WL:=ValueWhen(1,Nw,Ref(LowestSince(1,Nw,L),-1));

WCL:=ValueWhen(1,Nw,Ref(C,-1));

H4:=if(cum(1)=>x1t,((WH-WL)*1.1/2+WCL),0);
H3:=if(cum(1)=>x1t,((WH-WL)*1.1/4+WCL),0);
H2:=if(cum(1)=>x1t,((WH-WL)*1.1/6+WCL),0);
H1:=if(cum(1)=>x1t,((WH-WL)*1.1/12+WCL),0);
H5:=H4+1.168*(H4-H3);
L1:=if(cum(1)=>x1t, (WCL-(WH-WL)*1.1/12),0);
L2:=if(cum(1)=>x1t, (WCL-(WH-WL)*1.1/6),0);
L3:=if(cum(1)=>x1t, (WCL-(WH-WL)*1.1/4),0);
L4:=if(cum(1)=>x1t,(WCL-(WH-WL)*1.1/2),0);
L5:=L4-1.168*(L3-L4);
H5;H4;H3;H2;H1;L1;L2;L3;L4;L5

Comments

Merhaba,

Bu indikatörün bir versiyonunu gördüm.

FBB.L1

FBB.L2

FBB.L3

FBB.L4

FBB.L5

FBB.L6

FBB.L7

FBB.L8

FBE.L1

FBE.L2

FBE.L3

FBE.4

 

Bu bilindik bir indikatör mü?

Answer 1

Merhaba

NQ := ROC(INT((MONTH()-1)/3) <> Ref(INT((MONTH()-1)/3), -1), 1, $) < 0;
x1t := LastValue(ValueWhen(1, NQ = -1, Cum(1)));
WH := ValueWhen(1, NQ, Ref(HighestSince(1, NQ, H), -1));
WL := ValueWhen(1, NQ, Ref(LowestSince(1, NQ, L), -1));
WCL := ValueWhen(1, NQ, Ref(C, -1));
H4 := If(Cum(1) >= x1t, ((WH - WL) * 1.1 / 2 + WCL), 0);
H3 := If(Cum(1) >= x1t, ((WH - WL) * 1.1 / 4 + WCL), 0);
H2 := If(Cum(1) >= x1t, ((WH - WL) * 1.1 / 6 + WCL), 0);
H1 := If(Cum(1) >= x1t, ((WH - WL) * 1.1 / 12 + WCL), 0);
H5 := H4 + 1.168 * (H4 - H3);
L1 := If(Cum(1) >= x1t, (WCL - (WH - WL) * 1.1 / 12), 0);
L2 := If(Cum(1) >= x1t, (WCL - (WH - WL) * 1.1 / 6), 0);
L3 := If(Cum(1) >= x1t, (WCL - (WH - WL) * 1.1 / 4), 0);
L4 := If(Cum(1) >= x1t, (WCL - (WH - WL) * 1.1 / 2), 0);
L5 := L4 - 1.168 * (L3 - L4);
H5; H4; H3; H2; H1; L1; L2; L3; L4; L5

 

Bu şekilde çeyreklik dönemleri baz alarak deneyebilirsiniz.

 

Bilgilerinize.