Tarama Hakkında

Question

Merhaba iyi günler iyi çalışmalar.

Koşul 1- StokastikRsı al verecek

Koşul 2- Wto al verecek

Koşul 3- Mcdas Al verecek

Koşul 4 - Rsı 14 ema yukarı kesecek

Koşul 5- Macd dema al verecek

Koşul 6- Fiyat 8 ema üstünde olacak

Koşul 7- Hacim son 5 bar ortalamasının üzerinde olacak

Bu koşullardan 5 ve üzeri sağlamış olanların tarama formülünü yazabilir miyiz ?

Şimdiden Teşekkür ederim..

Answer 1

merhaba,

 

n1:=10;
n2:=21;
ap:=(H+L+C)/3;
esa:=mov(ap,n1,e);
d:=mov(abs(ap - esa),n1,e);
ci:=(ap-esa)/(0.015*d);
tci:=mov(ci,n2,e);
wt1:=tci;
wt2:=mov(wt1,4,s);
PK:=3;
PD:=3;
RPD:=14;
SPD:=14;
SRSI:=(RSI(C,RPD)-LLV(RSI(C,RPD),SPD))/(HHV(RSI(C,RPD),SPD)-LLV(RSI(C,RPD),SPD))*100;
K:=MOV(SRSI,PK,S);
D1:=MOV(K,PD,S);
DEMA12:=2*mov(c,12,e)-mov(mov(c,12,e),12,e);                         
DEMA26:=2*mov(c,26,e)-mov(mov(c,26,e),26,e);                         
MACDEMA:=DEMA12-DEMA26;                              
TRIGGER:=2*mov(MACDEMA,9,e)-mov(mov(MACDEMA,9,e),9,e) ;

(if(K>D1,1,0)+if(wt1>wt2,1,0)+if(MACDAS(26,12,9)>MACDASTrigger(26,12,9),1,0)+if(cross(RSI(c,14),mov(RSI(c,14),14,e)),1,0)+if(MACDEMA>TRIGGER,1,0)
+if(c>mov(c,8,e),1,0)+if(v>mov(v,5,s),1,0))>=5

 

formülünü kullanabilirsiniz,

bilgilerinize